/*équations :
S:=-3*x-3*y-3*x^2-3*x^2*z-3*y^2*x-6*x*y-6*x*z-3*y^2-6*y*z-3*x^2*y-3*x*z^2-3*y*z^2-6*x*y*z-3*y^2*z-3*z-3*z^2
*/
#include "colors.inc" 
#include "stones.inc" 
#include "metals.inc"

#declare r=0.008 ;
camera { orthographic 
          location <-2.5,0.6,-3>*0.75 look_at<0,0.2,0> }
 
light_source { <-4,5,-10> color White}
light_source { <-5,10,-20> color White shadowless}
light_source { <3,10,-10> color rgb <0.8,0.8,1>*0.5 shadowless}

box {<-20,-1.3,-20>,<5,20,5> 
      pigment {SkyBlue}
      rotate <0,5, 0>  
        }
//--------------------------------

union{
    poly {3, <0,-3,-3,-3,-3,-6,-6,-3,-6,-3,0,-3,-3,-3,-6,-3,0,-3,-3,0>

          texture{  /* pigment{ granite color_map{[0.0 rgb<1,1,0.7>][1.0 rgb<0.5,0.3,0>]}   scale 0.08   } */     
                 T_Silver_3C  
                  finish { ambient 0.4 diffuse 0.3 specular 0.5  reflection 0.04 roughness 0.008 }
  } 
}

#declare b=4; 
union{ 
cylinder{<-1/4*(-1+sqrt(5))*(2*b+1+sqrt(5)),b-1/2+1/2*sqrt(5),-b>,<-1/4*(-1+sqrt(5))*(-2*b+1+sqrt(5)),-b-1/2+1/2*sqrt(5),b>,r}
cylinder{<-1/4*(1+sqrt(5))*(-2*b-1+sqrt(5)),b-1/2-1/2*sqrt(5),-b>,<-1/4*(1+sqrt(5))*(2*b-1+sqrt(5)),-b-1/2-1/2*sqrt(5),b>,r}
cylinder{<b-1/2+1/2*sqrt(5),-1/2*(-1+sqrt(5))*(1-b),-b>,<-b-1/2+1/2*sqrt(5),-1/2*(-1+sqrt(5))*(1+b),b>,r}
cylinder{<b-1/2-1/2*sqrt(5),1/2*(1+sqrt(5))*(1-b),-b>,<-b-1/2-1/2*sqrt(5),1/2*(1+sqrt(5))*(1+b),b>,r}
cylinder{<1/2*(1+sqrt(5))*(1-b),b-1/2-1/2*sqrt(5),-b>,<1/2*(1+sqrt(5))*(1+b),-b-1/2-1/2*sqrt(5),b>,r}
cylinder{<-1/2*(-1+sqrt(5))*(1-b),b-1/2+1/2*sqrt(5),-b>,<-1/2*(-1+sqrt(5))*(1+b),-b-1/2+1/2*sqrt(5),b>,r}
cylinder{<-1/2*(-1+sqrt(5))*(1-b),-1/4*(-1+sqrt(5))*(2*b+1+sqrt(5)),-b>,<-1/2*(-1+sqrt(5))*(1+b),-1/4*(-1+sqrt(5))*(-2*b+1+sqrt(5)),b>,r}
cylinder{<1/2*(1+sqrt(5))*(1-b),-1/4*(1+sqrt(5))*(-2*b-1+sqrt(5)),-b>,<1/2*(1+sqrt(5))*(1+b),-1/4*(1+sqrt(5))*(2*b-1+sqrt(5)),b>,r}
cylinder{<-1/4*(1+sqrt(5))*(-2*b-1+sqrt(5)),1/2*(1+sqrt(5))*(1-b),-b>,<-1/4*(1+sqrt(5))*(2*b-1+sqrt(5)),1/2*(1+sqrt(5))*(1+b),b>,r}
cylinder{<-1/4*(-1+sqrt(5))*(2*b+1+sqrt(5)),-1/2*(-1+sqrt(5))*(1-b),-b>,<-1/4*(-1+sqrt(5))*(-2*b+1+sqrt(5)),-1/2*(-1+sqrt(5))*(1+b),b>,r}
cylinder{<b-1/2+1/2*sqrt(5),-1/4*(-1+sqrt(5))*(2*b+1+sqrt(5)),-b>,<-b-1/2+1/2*sqrt(5),-1/4*(-1+sqrt(5))*(-2*b+1+sqrt(5)),b>,r}
cylinder{<b-1/2-1/2*sqrt(5),-1/4*(1+sqrt(5))*(-2*b-1+sqrt(5)),-b>,<-b-1/2-1/2*sqrt(5),-1/4*(1+sqrt(5))*(2*b-1+sqrt(5)),b>,r}
cylinder{<-1,b,-b>,<-1,-b,b>,r}
cylinder{<0,b,-b>,<0,-b,b>,r}
cylinder{<b,0,-b>,<-b,0,b>,r}
cylinder{<0,-1,-b>,<0,-1,b>,r}
cylinder{<b,-1,-b>,<-b,-1,b>,r}
cylinder{<-1,0,-b>,<-1,0,b>,r}
cylinder{<0,-b,-1>,<0,b,-1>,r}
cylinder{<-1,-b,0>,<-1,b,0>,r}
cylinder{<-b,b,0>,<b,-b,0>,r}
cylinder{<-b,0,-1>,<b,0,-1>,r}
cylinder{<-b,b,-1>,<b,-b,-1>,r}
cylinder{<-b,-1,0>,<b,-1,0>,r}  
        pigment{ Red }
}
  // axes ----------------------
 union{          
   #declare g=0.9 ;
   #declare r1=0.02;
  
  #declare k=4;// longueur fleche=k*r1
  #declare co=1.8;// rayon base=co*r1
cylinder{ <-g/2,0,0>,<g,0,0>,r1 }
  cone{ <g,0,0>,co*r1,<g+k*r1,0,0>,0  }
  
  cylinder{ <0,-g/2,0>,<0,g,0>,r1  }
  cone{ <0,g,0>,co*r1,<0,g+k*r1,0>,0  }
  
  cylinder{<0,0,-g/2>,<0,0,g>,r1  }
  cone{ <0,0,g>,co*r1,<0,0,g+k*r1>,0 } 
  pigment { Yellow transmit 0.3}
   
}
  //-
    clipped_by { sphere{<0,0,0>,2.5 } }
  bounded_by { clipped_by }
  scale 0.7 
  rotate <-0,180,0>
  rotate <30,0,-27>
  translate <0,0.4,0>
}
        
text {	ttf "times.ttf" "AE"
        0.5,0 
        pigment { Cyan*1.2 }
        scale 0.08
        rotate <0,40,0> 
        translate <1.9,-1.3,-0.4> }