/*Parapluie de Whitney 
 
Tracé de cette cubique réglée et de deux droites de cette surface.
Equation : z*x^2 -y^2 =0 */

#include "colors.inc"    
#declare a=6 ;
#declare r=0.02 ;


#declare I_Glass = 
   interior{
      ior 1.51
      caustics 2
      fade_distance 1.5
      fade_power 1
   }

#declare T_Glass = texture {
   pigment { color red 0.1 green 1.0 blue 0.5 filter 0.75 }
   finish {
      ambient 0.2
      diffuse 0.0
      reflection 0.1
      phong 0.3
      phong_size 90
      specular 0.5
   }}
   
camera  { location <-2,1,-6> look_at <-0.1,0.3,0>}

light_source { <-20,20,-50> color rgb<0.8,1.2,1>*0.98 } 
light_source { <-10,-20,-50> color White*0.7} 
light_source { <-10,30,-30> color Yellow*0.8}

background {SkyBlue}

fog {
  fog_type   2
  distance   50
  color      SkyBlue
  fog_offset 0.1
  fog_alt    0.2
  turbulence 0.8
}
                            
union{
   union{    
         cylinder{<-a, -a, 1>,<a, a, 1>,r}
         cylinder{<-a, sqrt(2)*a, 2>,<a, -sqrt(2)*a, 2>,r}
         pigment{Yellow}
         finish {ambient 0.7 diffuse 0.4   roughness 0.01 }
        }
   cylinder{<0,0,-3*a>,<0,0,a>,r 
             pigment{Red}
             finish {ambient 0.7 diffuse 0.4   roughness 0.01 }
              }     
   intersection { 
       poly{3, <0,0,1.,0,0,0,0,0,0,0,0,0,-1.,0,0,0,0,0,0,0.>}//Whitney
       poly{3, <0,0,1.,0,0,0,0,0,0,0,0,0,-1.,0,0,0,0,0,0,0.> translate <0,0,-0.05> inverse }
     texture { T_Glass}
   interior { I_Glass}
   }
     clipped_by { sphere{ <0,0,-0.5>, 3.4
                  translate<0,0.,-0.>} }
   bounded_by { clipped_by }
   rotate <-120,30,-6.5> 
}

plane{ y,-10 
    
  pigment {checker
    color rgb <1, 1, 1>,
    color rgb <1, 0.8, 0*0.9>
    scale 5 
    }
    finish {ambient 0.8 diffuse 0.4   roughness 0.001 }
     }