/*Kuen's Surface
     x=2*(cos(u)+u*sin(u))*sin(v)/(1+u*u*sin(v)*sin(v))
      y=2*(sin(u)-u*cos(u))*sin(v)/(1+u*u*sin(v)*sin(v))
      z=log(tan(v/2))+2*cos(v)/(1+u*u*sin(v)*sin(v)) 
*/


#include "colors.inc"
#include "metals.inc"

//---------------------------------------
camera { orthographic location  < 5, 20,-20>
         look_at   <-0.5, -0.10, 0> angle 6.5
       } 

light_source { <0, 5,-20> color White shadowless}
light_source { <5,-10, -10>*2 color White*0.8  shadowless}

background{ SkyBlue*1.2 }//White }
//-----------------------------------


#macro cx(uu,vv)   2*(cos(uu)+uu*sin(uu))*sin(vv)/(1+uu*uu*sin(vv)*sin(vv)) #end
#macro cy(uu,vv)   2*(sin(uu)-uu*cos(uu))*sin(vv)/(1+uu*uu*sin(vv)*sin(vv)) #end
#macro cz(uu,vv)   log(tan(vv/2))+2*cos(vv)/(1+uu*uu*sin(vv)*sin(vv))  #end
//---------------------------------
# macro surf(umin,umax,vmin,vmax,uiter,viter)

#declare iu    = (umax-umin)/uiter ; 
#declare iv    = (vmax-vmin)/viter ;

union{      
  #declare uu = umin ;   
  #while (uu<umax)                        //boucle externe
    #declare vv = vmin ;
    #while (vv<vmax)                      //boucle interne
//POINTS      
      #declare x1=cx(uu,vv);
      #declare y1=cy(uu,vv);
      #declare z1=cz(uu,vv);
      #declare uu=uu+iu     ;
      #declare x2=cx(uu,vv);
      #declare y2=cy(uu,vv);
      #declare z2=cz(uu,vv);
      #declare vv=vv+iv   ;
      #declare x3=cx(uu,vv);
      #declare y3=cy(uu,vv);
      #declare z3=cz(uu,vv);
      #declare uu=uu-iu ;
      #declare x4=cx(uu,vv);
      #declare y4=cy(uu,vv);
       #declare z4=cz(uu,vv);
      #declare vv=vv-iv;  
  //NORMALES                  
      #declare uu=uu+2*iu ;                  //Calcul des normales
      #declare nx1=cx(uu,vv);
      #declare ny1=cy(uu,vv); 
      #declare nz1=cz(uu,vv);
      #declare uu=uu-2*iu ;
      #declare vv=vv+2*iv;
      #declare nx2=cx(uu,vv) ;
      #declare ny2=cy(uu,vv) ;
      #declare nz2=cz(uu,vv) ;
      #declare vv=vv-2*iv ;
      #declare uu=uu-iu ;
      #declare nx3=cx(uu,vv);
      #declare ny3=cy(uu,vv);
      #declare nz3=cz(uu,vv);
      #declare uu=uu+iu; 
      #declare vv=vv-iv ;
      #declare nx4=cx(uu,vv);
      #declare ny4=cy(uu,vv);
      #declare nz4=cz(uu,vv);
      #declare vv=vv+iv;     
  
      #declare n1=vcross(<nx2-x4,ny2-y4,nz2-z4>,<nx1-x2,ny1-y2,nz1-z2>);
      #declare n2=vcross(<x4-x3,y4-y3,z4-z3>,<nx2-x4,ny2-y4,nz2-z4>);   
      #declare n3=vcross(<nx3-x1,ny3-y1,nz3-z1>,<nx2-x4,ny2-y4,nz2-z4>);   
      #declare n4=vcross(<x3-x2,y3-y2,z3-z2>,<nx1-x2,ny1-y2,nz1-z2>); 
      #declare n5=vcross(<x1-x2,y1-y2,z1-z2>,<x3-x2,y3-y2,z3-z2>); 
      #declare n6=vcross(<nx3-x1,ny3-y1,nz3-z1>,<x4-x1,y4-y1,z4-z1>) ;
      #declare n7=vcross(<nx1-x2,ny1-y2,nz1-z2>,<nx4-x1,ny4-y1,nz4-z1>); 
      #declare n8=vcross(<nx4-x1,ny4-y1,nz4-z1>,<x1-x2,y1-y2,z1-z2>) ;  
      #declare n9=vcross(<nx4-x1,ny4-y1,nz4-z1>,<nx3-x1,ny3-y1,nz3-z1>);
     
 
//TRIANGLES      
      object{
              smooth_triangle{
                            <x1,y1,z1>,n5+n6+n8+n9,
                            <x2,y2,z2>,n4+n5+n7+n8,
                            <x3,y3,z3>,n1+n2+n4+n5
                             }
             }     
      object{
              smooth_triangle{
                            <x1,y1,z1>, n5+n6+n8+n9,  
                            <x3,y3,z3>, n1+n2+n4+n5   
                            <x4,y4,z4>, n2+n3+n5+n6  
                       }
             } 
      #declare vv = vv+iv;
   #end                 //boucle interne
   #declare uu = uu+iu;
 #end          //boucle externe 
}
#end //surface
//-----------------------------------


 union { 
        object{surf(-pi*1.8,0,0.1,pi-0.1,100,140)
                texture{     
              T_Silver_3C  
              normal {
              granite 1
              turbulence 0.4
              scale 0.1
              accuracy 0.6
                     } 
             }   
             finish {ambient 0.25 diffuse 0.25 reflection 0.25 roughness 0.0001 specular 0.8} 
              }       
        object{surf(0,pi*2.8,0.1,pi-0.1,100,140)    
               pigment{ Gold*1.2 }
               finish{ambient 0.05 reflection 0.1 specular 0.7 roughness 0.0001} 
        } 
       
      rotate <-65,190,-0> 
      translate <0.1,0.17,0>
   }

      
  object{surf(0,pi*2.8,0.1,pi-0.1,80,50)    
               pigment{ Gold*1.2 }
                finish{ambient 0. reflection 0.2 specular 0.6 roughness 0.0001}
               rotate <-65,190,-0> 
                scale 0.4 
               translate <-1.35,-1.4,0> 
               
        } 
          /*   */
//-----------------------------
text {	ttf "times.ttf" "AE"
        0.3,0                                                 
        pigment { Blue}
        scale 0.07
        rotate <40,0,12>
        translate <1,-1.3,0> 
        finish{ ambient 0.2 diffuse 0.3} }