#include "colors.inc"
#include "metals.inc" 
    
camera  { orthographic  location <-0,15,-30> look_at<0,-0.4,0> angle 11 } 
light_source { <-10,20,-20> White  shadowless } 
light_source { <10,15,-20> color White  shadowless} 
light_source { <4,-20,-15> color Orange*0.7  shadowless}

plane {z, 20  pigment{ SkyBlue*1.1}}
//background{White}
//-------------------------------------------

#declare umin  = 0;
#declare umax  = 1.5;
#declare vmin  =0; 
#declare vmax  =  4*pi;
#declare uiter = 100;
#declare viter = 200;
#declare iu    = (umax-umin)/uiter ; 
#declare iv    = (vmax-vmin)/viter;

#macro CX(uu,vv)  uu*cos(vv)-uu*uu/2*cos(2*vv)
   #end  
#macro CY(uu,vv)  -uu*sin(vv)-uu*uu/2*sin(2*vv)
   #end 
#macro CZ(uu,vv) 4/3*uu*sqrt(uu)*cos(3*vv/2) 
   #end 
//--------------- dM/duu -------------
#macro dCXu(uu,vv)
 cos(vv) -uu*cos(2*vv)
#end  
#macro dCYu(uu,vv)
 -sin(vv) -uu*uu*cos(2*vv)
#end 
#macro dCZu(uu,vv) 2*sqrt(uu)*cos(3*vv/2) 
#end 
//--------------- dM/dvv -------------
#macro dCXv(uu,vv)
 -uu*sin(vv)  +uu*sin(2*vv)
#end  
#macro dCYv(uu,vv)
  -uu*cos(vv)-uu*uu*cos(2*vv) 
#end 
#macro dCZv(uu,vv) -2*uu*sqrt(uu)*sin(3*vv/2) 
#end 


// ----------------------------------------

union{              // methode math
  #declare uu = umin;    
  #while (uu<=umax)                        //boucle externe
    #declare vv = vmin;
    #while (vv<=vmax)                      //boucle interne
//POINTS      
      #declare x1=CX(uu,vv); 
      #declare y1=CY(uu,vv);
      #declare z1=CZ(uu,vv) ; 
      #declare n1=vcross(<dCXu(uu,vv),dCYu(uu,vv),dCZu(uu,vv)>,<dCXv(uu,vv),dCYv(uu,vv),dCZv(uu,vv)>);
      #declare uu=uu+iu;                
      #declare x2=CX(uu,vv);
      #declare y2=CY(uu,vv); 
      #declare z2=CZ(uu,vv); 
      #declare n2=vcross(<dCXu(uu,vv),dCYu(uu,vv),dCZu(uu,vv)>,<dCXv(uu,vv),dCYv(uu,vv),dCZv(uu,vv)>);
      #declare vv=vv+iv ; 
      #declare x3=CX(uu,vv);
      #declare y3=CY(uu,vv);
      #declare z3=CZ(uu,vv);
      #declare n3=vcross(<dCXu(uu,vv),dCYu(uu,vv),dCZu(uu,vv)>,<dCXv(uu,vv),dCYv(uu,vv),dCZv(uu,vv)>);
      #declare uu=uu-iu ;
      #declare x4=CX(uu,vv);
      #declare y4=CY(uu,vv);
      #declare z4=CZ(uu,vv) ; 
      #declare n4=vcross(<dCXu(uu,vv),dCYu(uu,vv),dCZu(uu,vv)>,<dCXv(uu,vv),dCYv(uu,vv),dCZv(uu,vv)>);
      #declare vv=vv-iv;

//TRIANGLES      
      object{
              smooth_triangle{
                            <x1,y1,z1>,n1,
                            <x2,y2,z2>,n2,
                            <x3,y3,z3>,n3
                             }
             }     
      object{
              smooth_triangle{
                            <x1,y1,z1>, n1,  
                            <x3,y3,z3>, n3   
                            <x4,y4,z4>, n4  
                       }
             }
    
      #declare vv = vv+iv;
   #end                 // fin boucle interne
   #declare uu = uu+iu ;
 #end                  //fin boucle externe
                  
 texture{     
       T_Silver_5A
       normal {
           granite 1
           turbulence 0.5
           scale 0.2
           accuracy 0.5
       } 
        finish { ambient 0.4 diffuse 0.4 specular 0.3 roughness 0.01  }//ambient 0.3 fondblanc 
      }             
rotate <210,35,0>
}


 //-----------------------------------------


text {	ttf "times.ttf" "AE"
        0.3,0                                                 
        pigment { Blue}
        scale 0.1
        rotate <40,0,-2>
        translate <+3,-3,0> 
        finish{ ambient 0.2 diffuse 0.3} }